[TS Calls] Evaluate fallback policies and models with concrete replay

.github/workflows/ci.yml

@@ -188,7 +188,7 @@ jobs:
           node-version: 22
 
       - name: Run TS PBT integration baseline
-        run: env -u ARKANALYZER_DIR ETS_IR_PROVIDER=ts-frontend ./gradlew :usvm-ts-pbt:check
+        run: env -u ARKANALYZER_DIR ETS_IR_PROVIDER=ts-frontend ./gradlew :usvm-ts-pbt:check :usvm-ts-fast-check:check
 
   lint:
     runs-on: ubuntu-latest

build.gradle.kts

@@ -22,6 +22,8 @@ tasks.register("validateProjectList") {
             project(":usvm-jvm-instrumentation"),
             project(":usvm-python"),
             project(":usvm-ts"),
+            project(":usvm-ts-calls"),
+            project(":usvm-ts-fast-check"),
             project(":usvm-ts-pbt"),
             project(":usvm-ts-dataflow"),
         )

settings.gradle.kts

@@ -34,6 +34,8 @@ include("usvm-jvm:usvm-jvm-api")
 include("usvm-jvm:usvm-jvm-test-api")
 include("usvm-jvm:usvm-jvm-util")
 include("usvm-ts")
+include("usvm-ts-calls")
+include("usvm-ts-fast-check")
 include("usvm-ts-pbt")
 include("usvm-util")
 include("usvm-jvm-instrumentation")

usvm-ts-calls/build.gradle.kts

@@ -0,0 +1,86 @@
+plugins {
+    id("usvm.kotlin-conventions")
+    kotlin("plugin.serialization") version Versions.kotlin
+    application
+}
+
+dependencies {
+    implementation(project(":usvm-core"))
+    implementation(project(":usvm-ts"))
+    implementation(project(":usvm-ts-fast-check"))
+    implementation(project(":usvm-ts-pbt"))
+    implementation(Libs.jacodb_ets)
+    implementation(Libs.kotlinx_serialization_json)
+
+    testImplementation(Libs.logback)
+}
+
+val fastCheckAdapterDir = project(":usvm-ts-fast-check").layout.projectDirectory.dir("fast-check-adapter")
+val fastCheckRuntimeProperty = "org.usvm.ts.pbt.fastcheck.runtime"
+val generatedBuildMetadataDirectory = layout.buildDirectory.dir("generated/resources/callsBuildMetadata")
+val toolRevision = providers.exec {
+    workingDir(rootProject.projectDir)
+    commandLine("git", "rev-parse", "HEAD")
+}.standardOutput.asText.map(String::trim)
+val toolStatus = providers.exec {
+    workingDir(rootProject.projectDir)
+    commandLine("git", "status", "--porcelain", "--untracked-files=all")
+}.standardOutput.asText.map(String::trim)
+
+val generateBuildMetadata = tasks.register("generateBuildMetadata") {
+    inputs.property("toolRevision", toolRevision)
+    inputs.property("toolStatus", toolStatus)
+    outputs.dir(generatedBuildMetadataDirectory)
+
+    doLast {
+        val revision = toolRevision.get()
+        val buildIdentity = if (toolStatus.get().isBlank()) revision else "$revision-dirty"
+        val metadataFile = generatedBuildMetadataDirectory.get()
+            .file("org/usvm/ts/calls/build.properties")
+            .asFile
+        metadataFile.parentFile.mkdirs()
+        metadataFile.writeText("tool.revision=$buildIdentity\n", Charsets.UTF_8)
+    }
+}
+
+sourceSets.main {
+    resources.srcDir(generatedBuildMetadataDirectory)
+}
+
+tasks.processResources {
+    dependsOn(generateBuildMetadata)
+}
+
+tasks.test {
+    dependsOn(":usvm-ts-fast-check:buildFastCheckAdapter")
+    systemProperty(fastCheckRuntimeProperty, fastCheckAdapterDir.asFile.absolutePath)
+}
+
+application {
+    mainClass = "org.usvm.ts.calls.CallsExperimentCliKt"
+    applicationDefaultJvmArgs = listOf("-Dfile.encoding=UTF-8", "-Dsun.stdout.encoding=UTF-8")
+}
+
+tasks.named<JavaExec>("run") {
+    dependsOn(":usvm-ts-fast-check:buildFastCheckAdapter")
+    systemProperty(fastCheckRuntimeProperty, fastCheckAdapterDir.asFile.absolutePath)
+}
+
+distributions {
+    main {
+        contents {
+            into("lib/fast-check-adapter") {
+                from(fastCheckAdapterDir)
+                include("dist/src/**")
+                include("node_modules/**")
+                include("package.json")
+            }
+        }
+    }
+}
+
+listOf("startScripts", "installDist", "distZip", "distTar").forEach { taskName ->
+    tasks.named(taskName) {
+        dependsOn(":usvm-ts-fast-check:buildFastCheckAdapter")
+    }
+}