feat(examples): add complete example

Author: saumitra-dev

examples/complete/README.md

@@ -0,0 +1,18 @@
+# ECS EC2 Complete
+
+Configuration in this directory creates:
+
+- ECS Cluster using self-managed EC2
+- ECS Service configured for running Tasks on self-managed EC2
+
+## Usage
+
+To run this example, you will need to execute the commands:
+
+```bash
+terraform init
+terraform plan
+terraform apply
+```
+
+Please note that this example may create resources that can incur monetary charges on your AWS bill. You can run `terraform destroy` when you no longer need the resources.

examples/complete/main.tf

@@ -0,0 +1,69 @@
+provider "aws" {
+  region = local.region
+
+  default_tags {
+    tags = local.default_tags
+  }
+}
+
+locals {
+  region      = "ap-south-1"
+  name_prefix = "ex-"
+
+  # VPC
+  vpc_cidr            = "10.0.0.0/16"
+  vpc_azs             = ["ap-south-1a", "ap-south-1b"]
+  vpc_private_subnets = ["10.0.1.0/24", "10.0.2.0/24"]
+  vpc_public_subnets  = ["10.0.11.0/24", "10.0.12.0/24"]
+
+  # ECS Cluster
+  cluster_name = "${local.name_prefix}my-cluster"
+
+  # ECS Service
+  service_name = "${local.name_prefix}my-service"
+  service_task_resource_allocation = {
+    cpu    = 512
+    memory = 512
+  }
+
+  default_tags = {
+    Environment = "Dev"
+    ManagedBy   = "Terraform"
+  }
+}
+
+################################################################################
+# ECS EC2 Module
+################################################################################
+
+module "ecs_ec2" {
+  source = "../../"
+
+  # Cluster
+  cluster_name = local.cluster_name
+
+  # Services
+  service_name       = local.service_name
+  service_subnet_ids = flatten([module.vpc.private_subnets, module.vpc.public_subnets])
+  service_cpu        = local.service_task_resource_allocation.cpu
+  service_memory     = local.service_task_resource_allocation.memory
+}
+
+################################################################################
+# Supporting Resources
+################################################################################
+
+module "vpc" {
+  source  = "terraform-aws-modules/vpc/aws"
+  version = "~> 5.9.0"
+
+  name = "${local.name_prefix}my-vpc"
+  cidr = local.vpc_cidr
+
+  azs             = local.vpc_azs
+  private_subnets = local.vpc_private_subnets
+  public_subnets  = local.vpc_public_subnets
+
+  enable_nat_gateway = true
+  enable_vpn_gateway = false
+}

examples/complete/outputs.tf

@@ -0,0 +1,57 @@
+################################################################################
+# VPC
+################################################################################
+
+output "vpc_id" {
+  description = "Identifier of the VPC"
+  value       = module.vpc.vpc_id
+}
+
+output "vpc_cidr_block" {
+  description = "CIDR Block of the VPC"
+  value       = module.vpc.vpc_cidr_block
+}
+
+output "private_subnets" {
+  description = "Identifiers of the Private Subnets"
+  value       = module.vpc.private_subnets
+}
+
+output "private_subnets_arns" {
+  description = "ARNs of the Private Subnets"
+  value       = module.vpc.private_subnet_arns
+}
+
+output "private_subnets_cidr_blocks" {
+  description = "CIDR Blocks of the Private Subnets"
+  value       = module.vpc.private_subnets_cidr_blocks
+}
+
+output "public_subnets" {
+  description = "Identifiers of the Public Subnets"
+  value       = module.vpc.public_subnets
+}
+
+output "public_subnets_arns" {
+  description = "ARNs of the Public Subnets"
+  value       = module.vpc.public_subnet_arns
+}
+
+output "public_subnets_cidr_blocks" {
+  description = "CIDR Blocks of the Public Subnets"
+  value       = module.vpc.public_subnets_cidr_blocks
+}
+
+################################################################################
+# ECS EC2 Module
+################################################################################
+
+output "ecs_cluster_arn" {
+  description = "ARN of the ECS Cluster"
+  value       = module.ecs_ec2.cluster_arn
+}
+
+output "ecs_service_id" {
+  description = "Identifier of the ECS Service"
+  value       = module.ecs_ec2.service_id
+}

examples/complete/variables.tf

@@ -0,0 +1,10 @@
+terraform {
+  required_version = ">= 1.4.6"
+
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = ">= 5.57.0"
+    }
+  }
+}