build.gradle

// Java library
plugins { 
    id 'java-library'
    id 'maven-publish'
    id 'jacoco'
}

jacoco {
    toolVersion = "0.8.13"
}

jacocoTestReport {
    reports {
        xml.required = true
        html.required = true
    }
}

// Package default
base {
    archivesName = 'serpapi'
}
version = '1.1.0'
group = 'com.github.serpapi'

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
    withJavadocJar()
}

// Load repositories
repositories {
    mavenCentral()

    maven { url = "https://jitpack.io" }
}

dependencies {
    implementation 'com.google.code.gson:gson:2.9.0'
    
    // Use JUnit test framework
    testImplementation 'junit:junit:4.3'

    // Mockito
    testImplementation 'org.mockito:mockito-core:3.6.28'

    // javadoc markdown support doesn't work with modern java and gradle.
}

// jar file content
tasks.named('jar') {
    manifest {
        attributes('Implementation-Title': project.name,
                   'Implementation-Version': project.version)
    }
}

test {
    jacoco {
        // Avoid trying to instrument JDK internals on newest runtimes.
        excludes = ['java.*', 'jdk.*', 'sun.*']
    }

    testLogging {
        events "passed", "skipped", "failed"
        exceptionFormat = "short"
        showStackTraces = true
        showStandardStreams = true
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            pom { // To specify a license in the pom:
                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://github.com/serpapi/serpapi-java/blob/master/LICENSE'
                    }
                }
            }
        }
    }
}

wrapper {
    gradleVersion = "9.1.0"
    distributionType = Wrapper.DistributionType.ALL
}